1個のIPアドレスで4個のコンセントを制御できる4チャンネルスマートプラグ自作の記録

#define PUSH_BUTTON
#include <BlynkSimpleEsp8266.h>
#define BAUD_RATE 115200
#define DEBOUNCE_TIME 500
// define the GPIO connected with Relays and switches

#define DEVICES 4 // デバイス数
#define RELAYPIN_1 5 //D1
#define RELAYPIN_2 4 //D2
#define RELAYPIN_3 14 //D5
#define RELAYPIN_4 12 //D6

#define SWITCHPIN1 2 //D4
#define SWITCHPIN2 13 //D7
#define SWITCHPIN3 1 //D10 TX
#define SWITCHPIN4 3 //D9 RX

#define VPIN_1 V1 // Blynk vertual PIN
#define VPIN_2 V2
#define VPIN_3 V3
#define VPIN_4 V8

int wifiFlag = 0;

const char* ssid = "text";
const char* passphrase = "text";
BlynkTimer timer;
#define IRQ_TIME 3000L

#define TOGGLE_ON 0    //←機械式リレーのときはONが0、秋月電子に代表されるSSRではONが1
#define TOGGLE_OFF 1
#define AUTH "*****************" // You should get Auth Token in the Blynk App.
int VPIN[] = {VPIN_1,VPIN_2,VPIN_3,VPIN_4};
bool toggleState[DEVICES];               // リレー状態
bool lastSwitchState[DEVICES];           // 直前のスイッチ状態
unsigned long lastSwitchChange[DEVICES]; // 直前のスイッチ変更時間
int relayPINs[] = {RELAYPIN_1,RELAYPIN_2,RELAYPIN_3,RELAYPIN_4};
int switchPINs[] = {SWITCHPIN1,SWITCHPIN2,SWITCHPIN3,SWITCHPIN4};

/*
 * リレーを反転させる処理 relay=0オリジン
 */
void relayOnOff(int relay)
{
  bool toggleStateX = !toggleState[relay];
  digitalWrite(relayPINs[relay], toggleStateX); // turn on relay
  toggleState[relay] = toggleStateX;
  delay(100);
}

/*
 * リレーピンの初期化
 */
void setupRelays()
{
  for(int i = 0;i<DEVICES;i++){
    pinMode(relayPINs[i], OUTPUT);
    digitalWrite(relayPINs[i], TOGGLE_OFF); //
    toggleState[i] = TOGGLE_OFF;
  }
}

/*
 * スイッチピンの初期化
 */
void setupFlipSwitches()
{
  for(int i = 0;i<DEVICES;i++){
    lastSwitchChange[i] = 0;
    lastSwitchState[i] = HIGH;// INPUT_PULLUPの場合デフォルトはHIGH
    pinMode(switchPINs[i], INPUT_PULLUP);
  }
}
/* ループで毎回呼び出される
 * スイッチが押されていたらリレーを反転させトグルステート変数も反転させている
 */ 
void with_internet()
{
  for(int i=0;i<DEVICES;i++){
    unsigned long actualMillis = millis(); // get actual millis
    unsigned long lastSwitchChangeX = lastSwitchChange[i]; // get the timestamp when flipSwitch was pressed last time (used to debounce / limit events)
    if (actualMillis - lastSwitchChangeX > DEBOUNCE_TIME){ // if time is > debounce time...
      bool lastSwitchStateX = lastSwitchState[i]; // get the lastSwitchState
      bool flipSwitchStateX = digitalRead(switchPINs[i]); // read the current flipSwitch state
      if (flipSwitchStateX != lastSwitchStateX) { // if the Switch has changed...
        #ifdef PUSH_BUTTON
        if (!flipSwitchStateX) { // if the tactile button is pressed
          lastSwitchState[i] = !flipSwitchStateX;//2022-03-28修正 スイッチがプッシュかシーソーで動きが違うので変えた
        #else
          lastSwitchState[i] = flipSwitchStateX;
        #endif
          lastSwitchChange[i] = actualMillis; // update lastSwitchChange time
          relayOnOff(i);
          Blynk.virtualWrite(VPIN[i], toggleState[i]); // Update Button Widget
        #ifdef PUSH_BUTTON
        }
        #endif
      }
    }
  }
}

/* Blynkがつながったら一度だけ呼ばれる処理
 * ここの処理はいろいろやっていないのであれば
 * setup()内に入れてしまってもよい
 */
BLYNK_CONNECTED()
{
  for(int i=0;i<DEVICES;i++){
    // Request the latest state from the server
    Blynk.virtualWrite(VPIN[i],toggleState[i]);
  }
}

// When App button is pushed - switch the state
/* V? アプリで対応するバーチャルピンのボタンが押されたとき起動がかかる
 * 渡されるパラメータが1か0なのでそれをそのままリレーを叩くのに使ってしまっている
 */
BLYNK_WRITE(VPIN_1) 
{
  toggleState[0] = param.asInt();
  digitalWrite(relayPINs[0], toggleState[0]);
}
BLYNK_WRITE(VPIN_2) 
{
  toggleState[1] = param.asInt();
  digitalWrite(relayPINs[1], toggleState[1]);
}
BLYNK_WRITE(VPIN_3) 
{
  toggleState[2] = param.asInt();
  digitalWrite(relayPINs[2], toggleState[2]);
}
BLYNK_WRITE(VPIN_4) {
  toggleState[3] = param.asInt();
  digitalWrite(relayPINs[3], toggleState[3]);
}

/*
 * 3秒ごとに割り込みしてBlynkサーバーとつながっているかチェックしている
 * 本当はつながってなかったらほかにもやることあると思うけど省略
 */
void checkBlynkStatus() // called every 3 seconds by SimpleTimer
{
  bool isconnected = Blynk.connected();
  if (isconnected == false) {
    wifiFlag = 1;
  }
  if (isconnected == true) {
    wifiFlag = 0;
  }
}

/*
 * Wi-FiつなげてBlynkサーバーにつなげる
 * 3秒ごとのタイマー割り込み処理いれる
 */
void setup()
{
  Serial.begin(BAUD_RATE);
  setupRelays();
  setupFlipSwitches();
  ////// Wi-Fi接続処理 //////
  WiFi.begin(ssid, passphrase );
  timer.setInterval(IRQ_TIME, checkBlynkStatus); // check if Blynk server is connected every 3 seconds
  // タイマー割り込みのプロシージャを定義できる
  Blynk.config(AUTH);
}
/*
 * メインループ内ではWi-Fiがつながっていなければエラーメッセージをシリアルポートに出力する
 * ブリンクループ
 * タイマー処理
 * スイッチピン監視
 */
void loop()
{
  if (WiFi.status() != WL_CONNECTED){
    Serial.println("WiFi Not Connected");
  }else{
    Blynk.run();
  }
  timer.run(); // Initiates SimpleTimer
  with_internet();
}

if (!msg.payload) {
msg.payload = {
    command: "action.devices.commands.OnOff",
    params: {
        on: true
    }
};

delete msg._confId;

return msg;
} else {
    return;
}